$ !   Copyright © 2003, 2009, Oracle Corporation.  All Rights Reserved.
$ !++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
$ !  
$ !  R D B $ I M A G E _ V E R S I O N S
$ !  
$ !------------------------------------------------------------------------------
$ !  
$ !  FACILITY: Oracle Rdb
$ !  
$ !  ABSTRACT:
$ !  
$ ! This procedure displays image link time and version for potentially 
$ ! Rdb-related images in SYS$SHARE, SYS$SYSTEM  and SYS$MESSAGE.
$ ! This procedure works on OpenVMS IA64 and Alpha systems V7.3-2 and later.
$ !
$ !  PARAMETERS:
$ !   
$ !      P1 =	If passed, specifies a specfic file or wildcard.  Otherwise, 
$ !		filenames starting with RD*, SQL*, RM*, and COSI* and ending 
$ !		with .EXE are searched for and processed.
$ !
$ !  AUTHOR: Norman Lastovica
$ !  CREATION DATE: 24-APR-2003
$ !  MODIFICATION HISTORY:
$ !  
$ !   Version 7.2
$ !	12-May-09 31701 (NJL) Code cleanup.  Remove VAX.
$ !	26-Jun-08 31363 (NJL) Make a couple corrections.  Add KUS.
$ !   Version 7.1
$ !	13-Dec-03 28256 (NJL) Add ability to handle ELF images.
$ !   Version 7.0
$ !	24-APR-2003 (INI) Initial entry.
$ !  
$ !------------------------------------------------------------------------------
$ !
$ if p1 .eqs. ""
$ then
$  call li sys$system:rd*
$  call li sys$system:rmu*
$  call li sys$system:sql*
$  call li sys$system:cosi*
$  call li sys$system:kus*
$  call li sys$share:rd*
$  call li sys$share:rmu*
$  call li sys$share:sql*
$  call li sys$share:cosi*
$  call li sys$share:kus*
$  call li sys$message:rd*
$  call li sys$message:rmu*
$  call li sys$message:sql*
$  call li sys$message:cosi*
$  call li sys$message:kus*
$ else
$  call li 'p1
$ endif
$ exit
$li: subroutine
$ ifile = -
	f$parse(p1,".EXE;0","","NODE","SYNTAX_ONLY") +-
	f$parse(p1,".EXE;0","","DEVICE","SYNTAX_ONLY") +-
	f$parse(p1,".EXE;0","","DIRECTORY","SYNTAX_ONLY") +-
	f$parse(p1,".EXE;0","","NAME","SYNTAX_ONLY") +-
	f$parse(p1,".EXE;0","","TYPE","SYNTAX_ONLY") +-
	f$parse(p1,".EXE;0","","VERSION","SYNTAX_ONLY")
$lp:
$ imgfil = f$search(ifile)
$ if imgfil .eqs "" then goto bad
$ analyze/image/select=(link_time,identification)/nooutput 'imgfil'
$ ld=analyze$link_time
$ li=analyze$identification
$ if ld .nes. "" .and. li .nes. "" then -
	write sys$output f$fao("!44AS !16AS !17AS",imgfil,li,ld)
$ goto lp
$bad:
$ close /nolog img
$ exit
$ endsubroutine